#!/bin/bash
#
# xpath++ tool
#   https://www.ibm.com/developerworks/forums/thread.jspa?messageID=14511881&#14511881
#
if [ "$2" = "" ]; then
  echo "usage: `basename $0` <XPath expression> <XML file>"
  exit
fi
 
# for DataPower use comment out this line
xsltproc_xsl=/tmp/temp.xsl
 
 
if [ "$xsltproc_xsl" != "" ]; then
  sed -n "/<\!--delim-->/,/<\!--delim-->/p" $0 >$xsltproc_xsl
 
  xsltproc --stringparam xpathpar "$1" $xsltproc_xsl $2
 
  rm $xsltproc_xsl
else
  url=http://dp1-l3.boeblingen.de.ibm.com:2048/xpath
 
  curl -u "$1:" --data-binary @$2 $url; echo
fi
 
exit
 
 
<!--delim-->
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:date="http://exslt.org/dates-and-times"
  xmlns:dyn="http://exslt.org/dynamic"
  xmlns:exsl="http://exslt.org/common"
  xmlns:func="http://exslt.org/functions"
  xmlns:math="http://exslt.org/math"
  xmlns:random="http://exslt.org/random"
  xmlns:regexp="http://exslt.org/regular-expressions"
  xmlns:set="http://exslt.org/sets"
  xmlns:str="http://exslt.org/strings"
  xmlns:dp="http://www.datapower.com/extensions"
  extension-element-prefixes="dp dyn"
>
  <xsl:output method="xml" omit-xml-declaration="yes"/>
 
  <xsl:param name="xpathpar" />
 
  <xsl:template match="/">
    <xsl:variable name="xpath">
      <xsl:choose>
        <xsl:when test="function-available('dp:http-request-header')">
          <xsl:variable name="auth" 
            select="dp:http-request-header('Authorization')"/>
          <xsl:variable name="b64" 
            select="substring-after($auth,'Basic ')"/>
          <xsl:variable name="user_" 
            select="dp:binary-decode($b64)"/>
          <xsl:value-of
            select="substring($user_,1,string-length($user_)-1)"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$xpathpar"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
 
    <xsl:variable name="result" select="dyn:evaluate($xpath)"/>

    <xsl:choose>
      <xsl:when test="exsl:object-type($result)='node-set'">
        <xsl:for-each select="$result">
          <xsl:call-template name="doOutput"/>
        </xsl:for-each>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$result"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>


  <xsl:template name="doOutput">
    <xsl:text>
-------------------------------------------------------------------------------
</xsl:text>
    <xsl:choose>
      <xsl:when 
        test="self::comment() | 
              self::processing-instruction() | 
              self::text()">
        <xsl:copy-of select="."/>
      </xsl:when>
      <xsl:when 
        test="count(. | ../attribute::* | ../namespace::*) !=
              count(../attribute::* | ../namespace::*)">
        <xsl:copy-of select="."/>
      </xsl:when>
      <xsl:otherwise>
        <xsl:if test="count(. | ../namespace::*) = count(../namespace::*)">
          <xsl:text>xmlns</xsl:text>
          <xsl:if test="name()">:</xsl:if>
        </xsl:if>
        <xsl:value-of select="name()"/>
        <xsl:text>="</xsl:text>
        <xsl:value-of select="string()"/>
        <xsl:text>"</xsl:text>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
 
</xsl:stylesheet>
<!--delim-->